***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jul 1, 2024                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJD60N04S-AU     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs      s1    s2   205u TC=3m
Rg     g1    g2     0.809
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=366.2  VTO=2.39  LEVEL=3  VMAX=1e5  ETA=0.006  nfs=5.1797e11  gamma=0.92)
Rd     d1    d2    2.63e-3    TC=3.8e-3,1e-10
Dbd     s2    d2    Dbt
.MODEL     Dbt    D(BV=44  TBV1=5.355e-4 TBV2=6.055e-7  CJO=2.647e-9  M=1.252  VJ=9.092)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=2.599e-14  N=0.8179  RS=4e-5  EG=1.13  TT=20n ikf=9.99)
Rdiode  d1  21    1.814e-3 TC=5e-3
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   4.336e-10
.MODEL     DGD    D(M=1.930   cjo=4.315e-10   VJ=8.680)
Rpar      b    d2   10Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    2.773e-9
.ENDS PJD60N04S-AU
*$
